本人準備出一個ANSYS知識普及系列，將有用的網上資料歸攏，由于知識水平有限，不對之處請諒解。也歡迎各位網友提供好的資料分享，讓我們共同完成這個ANSYS知識普及系列。

編輯人：技術鄰ANSYS專家

業務咨詢網址：http://www.yqgqt.org.cn/content/other/402981 

（打個小廣告）

聲 明:1、ANSYS知識普及系列中所有資料均來自網上；

     2、如侵犯知識產權，請聯系ANSYS專家本人或者技術鄰，我將第一時間刪除。

小技巧：加本人關注，可以及時觀看本人發布的技術貼

從半空間無限域取一4X2的矩形平面結構，頂部中間一定范圍內受隨時間變化的均布荷載，荷載如下

p(t)=t        當0< DIV>

p(t)=2-t        當1<=t<=2時

p(t)=0        當t>2時

材料彈性模量E=2.5，泊松比0.25，密度1

網格尺寸0.1X0.1，在網格邊界上所有結點加法向和切向combin14號單元用以模擬粘彈性人工邊界（有關理論可參考劉晶波老師的相關文章）。combine14單元的兩個結點，其中一個與實體單元相連，另一個結點固定。網格圖如圖1所示

時程分析的時間步長為0.02秒，共計算16秒。計算得到四個控制點位移時程圖如圖2所示，控制點坐標A(0,2)、B(0,1)、C(0,0)、D(2,2).

計算所用命令流如下：

/PREP7
L=4      !水平長度
H=2          !豎起深度
E=2.5     !彈性模量
density=1   !密度
nu=0.25    !泊松比
dxyz=0.1   !網格尺寸

G    = E/(2.*(1.+nu))    !剪切模量
alfa = E*(1-nu)/((1.+nu)*(1.-2.*nu))  !若計算平面應力，此式需要修改
Cp=sqrt(alfa/density)    !壓縮波速
Cs=sqrt(g/density)     !剪切波速
R=sqrt(L*L/4.+H*H/4.)    !波源到邊界點等效長度

KbT=0.5*G/R*dxyz
KbN=1.0*G/R*dxyz
CbT=density*Cs*dxyz
CbN=density*Cp*dxyz

ET, 1, plane42,,,2   !按平面應變計算
et, 2, combin14, ,, 2    !切向
et, 3, combin14, ,, 2    !法向
r, 2, KbT, CbT
r, 3, KbN, CbN

  
MP, EX, 1, E
MP, PRXY, 1, nu
MP, DENS, 1, density

rectng,-L/2.,L/2,0.,H

asel, all
aesize, all, dxyz
mshape,0,2D
mshkey,1
amesh, all

!以下建立底邊界法向和切向彈簧阻尼單元
nsel,s,loc,y,0.
*get,np,node,,count      !得到選中的結點數，存入np
*get,npmax,node,,num,maxd    !得到已經定義的最大結點數，存入npmax
*do,ip,1,np
 npnum=node((ip-1)*dxyz-L/2.,0.,0.)
 x=nx(npnum)
 y=ny(npnum)
 z=nz(npnum)
 npmax=npmax+1
 n,npmax,x.,y-dxyz/2,z    !定義底邊界法向結點以便與邊界點形成法向單元
 type,3
 real,3
 e,npnum,npmax
 d,npmax,all,0.       !約束新生成的點
 npmax=npmax+1
 n,npmax,x-dxyz/2.,y,z    !定義底邊界切向結點以便與邊界點形成切向單元
 type,2
 real,2
 e,npnum,npmax
 d,npmax,all,0.       !約束新生成的點
*enddo

!以下建立左邊界法向和切向彈簧阻尼單元
nsel,s,loc,x,-L/2
*get,np,node,,count      !得到選中的結點數，存入np
*get,npmax,node,,num,maxd    !得到已經定義的最大結點數，存入npmax
*do,ip,2,np       !側邊界最下面一個點按底邊界上處理
 npnum=node(-L/2,(ip-1)*dxyz,0.)
 x=nx(npnum)
 y=ny(npnum)
 z=nz(npnum)
 npmax=npmax+1
 n,npmax,x-dxyz/2.,y,z    !定義左邊界法向結點以便與邊界點形成法向單元
 type,3
 real,3
 e,npnum,npmax
 d,npmax,all,0.       !約束新生成的點
 npmax=npmax+1
 n,npmax,x,y-dxyz/2.,z    !定義左邊界切向結點以便與邊界點形成切向單元
 type,2
 real,2
 e,npnum,npmax
 d,npmax,all,0.       !約束新生成的點
*enddo

!以下建立右邊界法向和切向彈簧阻尼單元
nsel,s,loc,x,L/2
*get,np,node,,count      !得到選中的結點數，存入np
*get,npmax,node,,num,maxd    !得到已經定義的最大結點數，存入npmax
*do,ip,2,np       !側邊界最下面一個點按底邊界上處理
 npnum=node(L/2,(ip-1)*dxyz,0.)
 x=nx(npnum)
 y=ny(npnum)
 z=nz(npnum)
 npmax=npmax+1
 n,npmax,x+dxyz/2.,y,z    !定義右邊界法向結點以便與邊界點形成法向單元
 type,3
 real,3
 e,npnum,npmax
 d,npmax,all,0.       !約束新生成的點
 npmax=npmax+1
 n,npmax,x,y-dxyz/2.,z    !定義右邊界切向結點以便與邊界點形成切向單元
 type,2
 real,2
 e,npnum,npmax
 d,npmax,all,0.       !約束新生成的點
*enddo

allsel,all
/pnum,type,1
/number,1
eplot
finish

/solu

ANTYPE,trans
!* 
TRNOPT,FULL
LUMPM,0

btime=0.02
etime=16.00
dtime=0.02
*DO,itime,btime,etime,dtime
 TIME,itime
 nsel,s,loc,y,H      !選中需要加荷載的點
 nsel,r,loc,x,-L/4,L/4
 *if,itime,lt,1.,then
  f,all,fy,1*itime
 *elseif,itime,ge,1.0,and,itime,le,2.0
  f,all,fy,1*(2-itime)
 *else
  f,all,fy,0.0
 *endif
 allsel,all
 SOLVE
*ENDDO

另外，還用自己編寫的有限元程序計算了一下這個例子，并與ANSYS得到的結果進行了比較，結果非常吻合，這里給出A點的比較結果。