行波效應的例子，三根梁的平面剛架，兩個固定基礎。
1）第一段命令流是不考慮行波效應，約束基礎，在全結構上施加加速度時程，
2）是不考慮行波效應，按照懶兄說的大質量法，在基礎上施加同樣加速度時程，得到的結果與1）在全結構施加加速度是一樣的。
3）考慮行波效應，大質量法，兩個基礎上作用不一樣的加速度歷程。
1）
!x方向基礎加速度，兩腳固定剛架，無行波效應的命令流
/UNITS,SI
/PREP7
ET,1,Beam3
MP,EX,1,210E9
MP,PRXY,1,0.3
MP,DENS,1,7800
R,1,3E-4,2.5E-9,0.01
N,1,0,0,0
N,2,10,0,0
N,3,20,0,0
N,4,0,-10,0
N,5,20,-10,0
E,1,2
E,2,3
E,4,1
E,5,3
D,4,all,
D,5,all,
dmprat,0.02
EPLOT
/solu
*dim,baseacel,array,500 ! 定義正弦波的“基礎加速度”, 500時間點
*do,i,1,500
baseacel(i)=0.1*sin(i*0.2) !
*enddo
NSUBST,1, , ,1 !1個子步
OUTRES,ALL,1 !輸出每個子步的結果
ANTYPE,TRANS !時程分析
*do,i,1,500
acel,baseacel(i),0,0
TIME,i*0.1
solve
*enddo
/POST26
NSOL,2,2,U,x,Ux-at-2
PLVAR,2 !plot displacement time history
deriv,3,2,1,,v2 ! v=dy/dt
deriv,4,3,1,,a2 ! a=dv/dt
!QUOT,9,2,10, , , , ,1,1,
!plvar,9
/wait,3
plvar,2,3,4 ! ! plot disp., velocity and acceleration history together
fini
/eof

2）
!x方向基礎加速度，兩腳固定剛架，
/UNITS,SI
/PREP7
ET,1,Beam3
MP,EX,1,210E9
MP,PRXY,1,0.3
MP,DENS,1,7800
R,1,3E-4,2.5E-9,0.01
N,1,0,0,0
N,2,10,0,0
N,3,20,0,0
N,4,0,-10,0
N,5,20,-10,0
E,1,2
E,2,3
E,4,1
E,5,3
D,4,all,
D,5,all,
EPLOT
!!!!Add large mass!!!
ET,2,MASS21
KEYOPT,2,3,4 ! 2D without rotational inertial
R,2,1e5,1e5,1e5,1e5,1e5,1e5,
type,2
real,2
mat,1
e,4
e,5
DDELE,4,UX ! 去掉基礎上待施加加速度方向的約束
ddele,5,ux
dmprat,0.02 ! 全結構阻尼比0.02
FINISH
/solu
*dim,baseacel,array,500 ! 定義正弦波的“基礎加速度”, 500時間點
*do,i,1,500
baseacel(i)=0.1*sin(i*0.2) !
*enddo
NSUBST,1, , ,1 !1個子步
OUTRES,ALL,1 !輸出每個子步的結果
ANTYPE,TRANS !時程分析
*do,i,1,500
f,4,fx,1e5*baseacel(i) ! F=m*a
f,5,fx,1e5*baseacel(i) ! 兩基礎上同步施加一樣的加速度，等于沒有行波效應
TIME,i*0.1
solve
*enddo
/POST26
NSOL,2,2,U,x,Ux-at-2 ! 2節點的絕對位移，不正確
PLVAR,2 !plot displacement time history
NSOL,5,5,U,x,Ux-at-2 ! 基礎的絕對位移
ADD,8,2,5, , , , ,1,-1,1, ! 2節點位移與基礎位移相減得到相對位移
plvar,8
deriv,3,8,1,,v2 ! v=dy/dt
deriv,4,3,1,,a2 ! a=dv/dt
/wait,3
plvar,3,4,8 ! ! plot disp., velocity and acceleration history together
fini
/eof

3）
!x方向基礎加速度，兩腳固定剛架，有行波效應的命令流
前面語句與上一個例子一樣，
/solu
*dim,baseace1,array,500 ! 定義正弦波的“基礎加速度”, 500時間點
*dim,baseace2,array,500
*do,i,1,500
baseace1(i)=0.1*sin(i*0.2) !
baseace2(i)=0.1*sin(i*0.2-0.4) !
*enddo
NSUBST,1, , ,1 !1個子步
OUTRES,ALL,1 !輸出每個子步的結果
ANTYPE,TRANS !時程分析
*do,i,1,500
f,4,fx,1e5*baseace1(i) ! F=m*a
f,5,fx,1e5*baseace2(i) ! 第二個基礎加速度比第一個相位滯后0.4,模擬一種行波效應
TIME,i*0.1
solve
*enddo
/POST26
NSOL,2,2,U,x,Ux-at-2 ! 2節點的絕對位移，不正確
PLVAR,2 !plot displacement time history
NSOL,5,5,U,x,Ux-at-2 ! 基礎的絕對位移
ADD,8,2,5, , , , ,1,-1,1, ! 2節點位移與基礎位移相減得到相對位移
plvar,8
deriv,3,8,1,,v2 ! v=dy/dt
deriv,4,3,1,,a2 ! a=dv/dt
/wait,3
plvar,3,4,8 ! ! plot disp., velocity and acceleration history together
fini
/eof