一、問題描述

厚度b = 500 mm的平壁，寬度W和高度H均為3 m。其左側表面溫度t₁ = 900 ℃，右側表面溫度t₂ = 250 ℃。假設平壁材料的導熱系數不隨溫度改變，導熱系數λ = 1.575 W/(m²·℃)。計算平壁內的溫度分布、導熱熱通量和溫度梯度。

---

二、問題分析

實際物體均是具有空間的三維結構，由于本例只沿著壁厚這一個方向進行熱傳導，因此可通過三種方式建立模型：

（1）一維模型：由于本例熱傳導只沿著壁厚方向，可簡化成一維的傳熱問題。采用熱分析LINK33桿單元，平壁面積由實常數輸入。實常數中輸入面積（寬度W 乘以高度H）9 m²，平壁的壁厚b則是熱分析LINK33單元的長度。見圖1(1)。

（2）二維模型：采用熱分析PLANE77平面單元，在單元選項中選擇帶有厚度的平面，見圖2.1.1(2)。平面的厚度即為平壁的壁厚b，平面的高度H輸入3 m；見圖1(2)。

（3）三維模型：采用熱單元SOLID70三維單元，沿著傳熱方向即為平壁的壁厚b，寬度W和高度H輸入3 m。見圖1(3)。

材料屬性中輸入導熱系數（導熱率）。在后處理中，輸出溫度、熱通量和溫度梯度的云圖，提取導熱速率的數值。

---

三、熱通量、溫度梯度和導熱速率與解析解對比 

圖2給出了三維模型的熱分析結果云圖，表1給出了熱傳導分析計算結果對比。本算例為單層平壁導熱問題，熱量只沿壁厚方向傳遞，沿著垂直壁厚的其他兩個方向認為無熱量傳遞，因此采用一維、二維和三維模型的計算結果相同。

 (1) 溫度云圖

(2) 溫度梯度和熱通量云圖

圖2 熱分析結果云圖

---

四、計算步驟  

1．進入ANSYS

程序→ANSYS → ANSYS Product Launcher→ 改變working directory到指定文件夾→job name：輸入file。

2．設置計算類型

Main Menu> Preferences→ 選擇Thermal→ OK。

3．定義單元屬性

（1）單元類型，見圖3。Main Menu> Preprocessor> Element Type> Add/ Edit/ Delete→ Add→ 選擇SOLID70單元，即在左列表框中選擇Thermal Solid，在右列表框中選擇Brick 8node 70→ OK。

圖3 熱分析單元

（2）熱傳導系數，見圖4。Main Menu> Preprocessor> Material Props> Material Models→ Thermal→Conductivity → Isotropic → KXX輸入1.575→ OK。

圖4 導熱系數

4．建立幾何模型

（1）建立幾何體，見圖5。Main Menu> Preprocessor> Modeling> Create> Volumes> Block> By Dimensions→ X1, X2輸入0和0.5，Y1, Y2輸入0和3，Z1, Z2輸入0和3。

圖5 三維幾何體

（2）ISO視圖顯示：屏幕右上角單擊IsometricView   → 屏幕中單擊右鍵。

5．劃分單元

（1）設置單元屬性：Main Menu> Preprocessor> Meshing> Mesh Tool→在Element Attributes下方選擇Volumes，點按Set→Pick All→ OK→ 選擇MAT: 1，TYPE: 1 → OK。

（2）設置單元尺寸：Main Menu> Preprocessor> Meshing> Mesh Tool→ 在Size Controls下方選擇GlobalSet→ SIZE中輸入0.25→ OK。

（3）劃分網格：Main Menu> Preprocessor> Meshing> Mesh Tool→ 選擇Volumes, Hex, Mapped→ Mesh→  Pick All→ OK。

（4）保存網格模型：Utility Menu> File> Save as→ 輸入Thermal_mesh.db。

6．施加邊界條件

（1）打開面編號：Utility Menu> PlotCtrls> Numbering→ /PNUM中選擇AREA→ OK。

（2）顯示面：Utility Menu> Plot>Areas。

（3）施加壁面溫度邊界

①左側表面溫度t₁=900℃，見圖6。Main Menu> Solution>Define Loads> Apply> Thermal> Temperature> On Areas →拾取面A5 → OK → Lab2中選擇TEMP；VALUE輸入900 → OK。

圖6 施加溫度邊界

②右側表面溫度t₂=250℃：Main Menu> Solution> DefineLoads> Apply> Thermal> Temperature> On Areas →拾取面A6 → OK → Lab2中選擇TEMP；VALUE輸入250→ OK。

7．求解

（1）求解前保存模型：Utility Menu> File> Save as→ 輸入Thermal_load.db。

（2）求解前選擇所有：Utility Menu> Select> Everything。

（3）開始求解計算：Main Menu> Solution> Slove> Current LS→ File> Close→ OK→  [Sloution is done]: Close，完成求解計算。

（4）求解后保存模型：UtilityMenu> File> Save as→ 輸入Thermal_solve.db。

8．通用后處理

圖7 云圖結果

（1）溫度分布云圖：見7(1)。MainMenu> General Postproc> Plot Results> Contour Plot> Nodal Solu→Nodal Solution→ DOF Solution→ Nodal Temperature→ OK。單位：℃。

（2）溫度梯度云圖：見7(2)。MainMenu> General Postproc> Plot Results> Contour Plot> Nodal Solu→Nodal Solution→ DOF Solution→ Thermal Gradient→ OK。單位：℃/m。

（3）熱通量云圖：見7(3)。Main Menu> General Postproc>Plot Results> Contour Plot> Nodal Solu→ Nodal Solution→ DOF Solution→Thermal Flux→ OK。單位：W/m²。

圖8 熱流量

（4）計算熱流量

①選擇面A5：見8(1)。Utility Menu> Select> Entities →從上到下依次選擇：Areas，By Num/Pick，From Full，OK →拾取面A5。

②顯示面：Utility Menu> Plot>Areas。

③節點依附到面上：見8(2)。Utility Menu> Select> Entities →從上到下依次選擇：Nodes，Attached to，Areas all，From Full，Apply，Replot。

④顯示節點：Utility Menu> Plot> Nodes。

⑤計算熱流量：見8(3)。Main Menu> General Postproc> Nodal Calcs>Total Force Sum。計算得出的熱流量為-18427.50 W，見8(4)。熱流量負值表示流入，正值表示流出。

---

五、命令流

!《化工原理》，第三版，楊祖榮，第124頁

b1=500e-3       !平壁厚度

lambda1=1.575  !導熱系數（熱導率），W/(m.℃)

t1=900         !左側表面溫度

t2=250         !右側表面溫度

W1=3          !平壁寬度

H1=3          !平壁高度

A1=W1*H1

dt=t1-t2

R1=b1/(lambda1*A1)   !導熱熱阻

Q1=dt/R1            !導熱速率W

TF=Q1/A1           !熱通量（W/m^2）Thermal Flux

TG=TF/lambda1      !溫度梯度（m/℃）Thermal Gradient

!-----------------------------一維模型------------------------

/PREP7

ET,1,LINK33        !熱單元

R,1,9,              !傳熱面積

MP,KXX,1,1.575     !導熱系數（熱導率）

K,1,0,0,0,           !關鍵點

K,2,0.5,0,0, 

LSTR,1,2            !幾何線

ESIZE,0.25,0,        !單元尺寸

LMESH,1

/VIEW,1,1,1,1

DK,1,,900,,0,TEMP    !左側溫度

DK,2,,250,,0,TEMP    !右側溫度

FINISH

/SOL

SOLVE

FINISH

/POST1

/ESHAPE,1

PLNSOL,TEMP,,0     !溫度分布℃

PLNSOL,TG,X,0      !溫度梯度℃/m

PLNSOL,TF,X,0      !熱通量W/m2

!-----------------------------二維模型------------------------

/PREP7

ET,1,PLANE77        !熱單元

MP,KXX,1,1.575       !導熱系數（熱導率）

RECTNG,0,0.5,0,3,     !幾何面

ESIZE,0.25,0,          !單元尺寸

MSHAPE,0,2D 

MSHKEY,1

AMESH,all 

DL,4,,TEMP,900,0      !左側溫度

DL,2,,TEMP,250,0      !右側溫度

FINISH

/SOL

ALLSEL,ALL

SOLVE 

FINISH 

/POST1 

PLNSOL, TEMP,, 0      !溫度云圖℃

PLNSOL, TG,X, 0       !溫度梯度℃/m

PLNSOL, TF,X, 0        !熱通量W/m2

LSEL,S,,,4             !選擇線L4

LPLOT                !顯示線

NSLL,S,1              !節點依附到線

NPLOT                !顯示節點

FSUM,0,ALL           !計算熱流量

!-----------------------------三維模型------------------------

/PREP7

ET,1,SOLID70          !熱單元

MP,KXX,1,1.575        !導熱系數（熱導率）

BLOCK,0,0.5,0,3,0,3,     !三維幾何體

ESIZE,0.25,0,           !單元尺寸

MSHAPE,0,3D 

MSHKEY,1

VMESH,1 

DA,5,TEMP,900        !左側溫度

DA,6,TEMP,250        !右側溫度

FINISH

/SOL

ALLSEL,ALL

SOLVE 

FINISH 

/POST1 

PLNSOL, TEMP,, 0      !溫度云圖℃

PLNSOL, TG,X, 0       !溫度梯度℃/m

PLNSOL, TF,X, 0       !熱通量W/m2

ASEL,S,,,5             !選擇面A5

APLOT                !顯示面

NSLA,S,1              !節點依附到面

NPLOT                !顯示節點

FSUM,0,ALL           !計算熱流量