! ANSYS單元生死功能模擬門式剛架施工
! Simulate the construction of a frame with the element active/kill
! function of ANSYS
! 施工分為三步
! The construction is divided into 3 steps
! 1: 建立立柱和臨時支撐
! 1: Install the column and temporary support
! 2: 安裝橫梁
! 2: Install the beams
! 3: 去掉臨時支撐
! 3: Remove the temporary support
! 作者：陸新征，清華大學土木系
! Author: Lu Xinzheng Dept. Civil Engrg. of Tsinghua University

[Money=20]

FINISH
/CLEAR
/UNITS,SI
/PREP7
!*
SECTWIDTH=300 !構件截面寬度300MM
SECTHEIGHT=600 !構件截面高度600MM
SECTAREA=SECTWIDTH*SECTHEIGHT
SECTIYY=SECTWIDTH**3*SECTHEIGHT/12.
SECTIZZ=SECTWIDTH*SECTHEIGHT**3/12.

SPAN=24E3 !跨度24M
COLUMNHEIGHT=8E3 !柱子高度8M
SLOP=3E3 !頂部斜坡3M

ET,1,BEAM4
R,1,SECTAREA,SECTIYY,SECTIZZ,SECTHEIGHT,SECTWIDTH, ,

MP,EX,1,30E3
MP,NUXY,1,0.2
MP,DENS,1,2500E-12

K,1,
K,2,SPAN/2,0
K,3,SPAN
K,4,0,COLUMNHEIGHT
K,5,SPAN,COLUMNHEIGHT
K,6,SPAN/2.,COLUMNHEIGHT+SLOP
L,1,4 !左立柱 Left column
L,2,6 !臨時支撐 Temporary support
L,3,5 !右立柱 Right Column
L,4,6 !左橫梁 Left Beam
L,5,6 !右橫梁 Right Beam
LESIZE,ALL, , ,1 , , , , ,1
LMESH,ALL
/ESHAPE,1.0
FINISH

/SOLU
CNVTOL,F,,0.001,2,
NLGEOM,1
AUTOTS,0
NSUBST,3, , ,1

DK,1,ALL
DK,3,ALL
DK,2,ALL
ACEL,0,9.8E3,

!殺死橫梁
! Kill Beams
EKILL, 4
EKILL, 5

SOLVE
FINISH
/POST
PARSAV, ALL, PARAM, TXT,
FINISH
/SOLU
ANTYPE,,REST,
PARRES, CHANGE , PARAM, TXT,

!激活橫梁
! Active beams
EALIVE,4
EALIVE,5
SOLVE
FINISH
/POST
PARSAV, ALL, PARAM, TXT,
FINISH
/SOLU
ANTYPE,,REST,
PARRES, CHANGE , PARAM, TXT,
!激活橫梁
! Active beams
EALIVE,4
EALIVE,5
!殺死臨時支撐
! Kill Supports
EKILL,2
SOLVE
FINISH
/POST

/DSCALE,1,10
/REPLOT