!* 利用ANSYS計算土壤中管道溫度應(yīng)力
!* Example for thermal stress of a pipe inside soil with ANSYS
! 作者：陸新征，清華大學土木工程系
! Author: Lu Xinzheng Dept. Civil Engrg. of Tsinghua University
!* Feb, 15, 2006
!*
*SET,R1,5 ! 內(nèi)徑大小
*SET,R2,6 ! 外徑大小
*SET,L,20 ! 土體計算范圍
/prep7
!* 生成關(guān)鍵點模型
k,1001,0,0,
k,1,0,R1,
k,2,0,-R1
k,3,R1,0
k,4,0,-R2
k,5,R2,
k,6,0,R2
k,7,0,-L
k,8,L,-L
k,9,l,0
k,10,L,l
k,11,0,L

!* 生成線段
l,1,6
larc,1,3,1001,R1
larc,3,2,1001,R1
l,2,4
larc,5,4,1001,R2
larc,6,5,1001,R2
l,3,5
l,4,7
l,7,8
l,8,9
l,5,9
l,9,10
l,10,11
l,6,11

al,3,4,5,7
al,1,2,7,6
al,8,9,10,11,5
al,11,12,13,14,6

ET,1,PLANE42
!*
!* 混凝土材料
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,EX,1,,30e9
MPDATA,PRXY,1,,0.2
MPTEMP,,,,,,,,
MPTEMP,1,0
UIMP,1,REFT,,,
MPDATA,ALPX,1,,1e-5 ! 熱膨脹系數(shù)
!* 土壤材料
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,EX,2,,30e6
MPDATA,PRXY,2,,0.2

!* 設(shè)定材料屬性
asel,s,,,1,2,
AATT, 1, , 1, 0,
asel,s,,,3,4,
AATT, 2, , 1, 0,
ALLSEL,ALL

!* 設(shè)定單元尺寸
ESIZE,R2/6,0,
MSHAPE,0,2D
MSHKEY,0
!* 劃分網(wǎng)格
amesh,all

FINISH
/SOL
!* 靜力分析
ANTYPE,0
!* 對稱邊界條件
lsel,s,,,1,
lsel,a,,,4,
lsel,a,,,8,
lsel,a,,,14,
nsll,s,1
d,all,UX,0
!* 四周土體約束
lsel,s,,,9,10,
lsel,a,,,12,
nsll,s,1
d,all,all,
lsel,s,,,2,3
nsll,s,1
!* 在管道內(nèi)表面施加溫度荷載200攝氏度
BF,ALL,TEMP,200
!* 建立所有屬于管道單元的節(jié)點選擇集
allsel,all
asel,s,,,1,2
nsla,s,1
cm,N_Area,Node
!* 建立所有管道外表面節(jié)點選擇集
lsel,s,,,1,6,
nsll,s,1
cm,N_Line,Node
!* 將管道中所有節(jié)點排除表面節(jié)點得到管道的內(nèi)部節(jié)點
cmsel,s,N_Area,Node
cmsel,u,N_Line,Node
!* 在所有內(nèi)部節(jié)點上時間100攝氏度的溫度荷載
BF,all,TEMP,100
allsel,all
!* 求解
solve
!*
FINISH
/POST1
!* 得到管道及周圍土體變形圖
SET,LAST
PLDISP,2
/AUTO, 1
/REP