本文介紹聯(lián)軸體的建模以及靜力學分析，適合初級入門用戶熟悉ANSYS軟件GUI操作，學習APDL命令流。

本實例求解聯(lián)軸體在工作時的應力和形變。聯(lián)軸體結構如下圖所示。

 

聯(lián)軸體的底面四周的邊線不能上下移動（Z方向0位移約束），底面的兩個圓其邊線上約束所有自由度。

在小軸孔的軸臺和小軸孔圓周上加載壓力1e6Pa，在大軸孔的軸臺和鍵槽一側(cè)分別加載有壓力1e7Pa和1e5Pa。

最后求其變形和應力情況并查看應力動畫。

/CLEAR,START            

/FILNAME,lianzouti,0  !jobname 命令為lianzouti,不新建log和error文件

/PREP7  !進入前處理

!**************幾何建模****************

CYL4,0,0,5, , , ,10    !創(chuàng)建圓柱體1

CYL4,12,0,3, , , ,4    !創(chuàng)建圓柱體2

LPLOT             !顯示線

LOCAL,11,1,0,0,0, , , ,1,1,     !創(chuàng)建11號局部坐標系

K,110,5,-80.4,0,      !在大圓柱體下表面創(chuàng)建點110

K,120,5,80.4,0,      !在大圓柱體下表面創(chuàng)建點120

LOCAL,12,1,12,0,0, , , ,1,1,    !創(chuàng)建12號局部坐標系

K,130,3,-80.4,0,      !在小圓柱體下表面創(chuàng)建點130

K,140,3,80.4,0,       !在小圓柱體下表面創(chuàng)建點140

LSTR,    110,     130 

LSTR,    120,     140 

LSTR,    130,     140 

LSTR,    110,     120  !連接關鍵點生成直線

/PNUM,LINE,1

/REPLOT         !顯示線編號

AL,21,22,23,24    !連接21,22,23,24號線生成面

VOFFST,9,4, ,      !將剛生成的9號面沿面法向拉伸距離4

CSYS,0          !當前坐標系更改為總體笛卡爾坐標系

WPAVE,0,0,8.5    !向Z方向移動工作平面8.5

VSBV,3,1,,,KEEP    !布爾減運算

NUMCMP,VOLU    !壓縮體編號

CYL4,0,0,3.5, , , ,1.5 

CYL4,0,0,2.5, , , ,-8.5   !創(chuàng)建大圓柱體內(nèi)孔

VSBV,1,5

VSBV,6,4            !布爾運算減去內(nèi)部兩個圓柱

NUMCMP,VOLU    !壓縮體編號

WPAVE,0,0,0      !偏移工作平面至原點

BLOCK,0,-3,-0.6,0.6,0,8.5,   !創(chuàng)建鍵槽矩形

VSBV,1,4         !減去鍵槽矩形

NUMCMP,VOLU    !壓縮體編號

WPAVE,12,0,2.5   

VSBV,2,1,,,KEEP     !右側(cè)圓柱與底板布爾運算

NUMCMP,VOLU    !壓縮體編號

CYL4,0,0,2, , , ,1.5

CYL4,0,0,1.5, , , ,-2.5  !創(chuàng)建小圓柱體內(nèi)孔

VSBV,1,4

VSBV,6,5          !布爾運算減去內(nèi)部兩個圓柱

VADD,ALL         !布爾加操作

!**************定義單元與材料****************

ET,1,SOLID187   !定義單元類型為10節(jié)點4面體實體單元

MPTEMP,,,,,,,, 

MPTEMP,1,0 

MPDATA,EX,1,,2.06E11

MPDATA,PRXY,1,,0.3 

MPTEMP,,,,,,,, 

MPTEMP,1,0 

MPDATA,DENS,1,,7800  !定義材料屬性

ESIZE,1,0,             !網(wǎng)格尺寸設置為1

VMESH,ALL            !自由分網(wǎng)

!**************定義約束與載荷****************

LPLOT

LSEL,S, , ,2,3

LSEL,A, , ,21,22

LSEL,A, , ,87

LSEL,A, , ,89

DL,ALL, ,UZ,    !限制以上所選線條Z向自由度

ALLSEL

LSEL,S, , ,46

LSEL,A, , ,49

LSEL,A, , ,74

LSEL,A, , ,76

LSEL,A, , ,78,80,1

LSEL,A, , ,66

DL,ALL, ,ALL,   !限制以上所選線條的所有自由度

ALLSEL

/PNUM,LINE,0    !取消線編號

/PNUM,AREA,1   !顯示面編號

SFA,24,1,PRES,1e6

SFA,26,1,PRES,1e6

SFA,17,1,PRES,1e6   !在小軸孔的內(nèi)表面和軸臺上加壓力1e6

SFA,32,1,PRES,1e7   !在軸孔軸臺上加載壓力1e7

SFA,28,1,PRES,1e5   !在鍵槽一側(cè)加載壓力1e5

/SOL

SOLVE

FINISH

!**************結果后處理****************

/POST1

PLNSOL, U,X, 2,1.0 

PLNSOL, U,Y, 2,1.0  

PLNSOL, U,Z, 2,1.0       !顯示X、Y、Z方向的位移

PLNSOL, S,X, 2,1.0       !顯示X方向的應力

PLNSOL, S,EQV, 2,1.0     !顯示等效應力

---

---

應力動畫：

結語：由于網(wǎng)格差異，本命令流與視頻中的求解結果有細微差別，讀者重在熟悉了解建模分析過程。