導讀：掌握壓桿不同約束條件的施加和特征值屈曲分析方法，臨界載荷等于施加的載荷乘以特征值。

---

一、模型演示

以下模型實驗演示了不同邊界條件下受壓桿件的屈曲現象和對應的屈曲變形。實驗中采用塑料尺來模擬桿件，我們可以感受到使塑料尺發生屈曲時所需力的大小。

(1)將塑料尺的一端置于桌面上，另一端用手掌加以固定，下壓塑料尺的頂部并逐步增加壓力，直尺會突然產生如圖a所示的側向變形。進一步增加壓力，變形也會相應的增大。本實驗演示了兩端鉸支桿件的屈曲現象。

圖a  兩端鉸支

(2)用手指將塑料尺的兩端捏緊，防止其發生選裝和平動。然后對直尺逐漸施加壓力直至出現如圖b所示的側向變形。本實驗演示了兩端固定桿件的屈曲現象。可以明顯感受到本實驗所需的臨界壓力要大于前一個實驗。

圖b 兩端固定

(3)如果在塑料尺中部設置一側向支撐，以保證尺子在這點不會發生平動，則需要施加比第一個實驗更大的壓力才能使塑料尺發生如圖c所示的屈曲變形。

圖c 中部側向支撐

模型演示圖片來源：英國曼徹斯特大學季天健教授。

---

二、定義和概念

穩定性：平衡物體在其原來平衡狀態下抵抗干擾的能力。

失穩：不穩定的平衡物體在任意微小的外界干擾下的變化或破壞過程，也稱為屈曲。

臨界載荷：使結構介于穩定平衡和不穩定平衡之間的載荷，或使結構處于屈曲臨界狀態的載荷。

平衡的三種狀態：穩定平衡、隨遇平衡（臨界狀態）、不穩定平衡。

---

三、問題描述

鋼板尺子長度500mm，寬度39mm，厚度1.2mm。彈性模量E= 200 GPa，泊松比u =0.3。

分別受以下4種約束作用：

(1)兩端鉸支，

(2)一端固定、另一端自由，

(3)一端固定、另一端鉸支，

(4)兩端固定。

計算在各種約束情況下的臨界載荷。

問題分析：對于這4種約束作用，對應的邊界條件見下圖所示。

臨界載荷計算結果：

四、APDL步驟

Ex=2e5      !彈性模量MPa

b=1.2        !截面寬度mm

h=39        !截面長度mm

Len=500     !壓桿長度mm

I=h*b**3/12            !慣性矩

pi=ACOS(-1)

miu=1                                            !長度因數

Fcr=pi**2*Ex*I/(miu*Len)**2     !第1階失穩載荷解析解

 

/PREP7   

ET,1,BEAM188        !單元類型

KEYOPT,1,3,3         !形函數

 

SECTYPE,   1, BEAM, RECT, , 0    !截面屬性

SECOFFSET, CENT

SECDATA,1.2,39,0,0,0,0,0,0,0,0,0,0

 

MP,EX,1,2e5            !材料屬性

MP,PRXY,1,0.3

 

K,1,0,0,0,                 !創建關鍵點 

K,2,0,500,0 

L,1,2                           !創建直線

  

LESIZE,1,50, , , , , , ,1    !單元尺寸mm

LMESH,1                              !分網

 

DK,1,UX               !下端鉸支

DK,1,UY

DK,1,UZ

DK,1,ROTY

DK,2,UX               !上端鉸支

DK,2,UZ

 

FK,2,FY,-1              !施加單位載荷

 

FINISH 

/SOLU

PSTRES,1         !打開預應力

SOLVE               !求解

FINISH               !退出求解器

 

/SOLU

ANTYPE,1              !分析類型-特征值屈曲

 

BUCOPT,SUBSP,1,0,0     !特征值屈曲分析選項SUBOPT,0,0,0,0,0,ALL

 

MXPAND,1,0,0,0,0.001,    !擴展模態數

SOLVE                                     !求解

 

FINISH

/POST1

SET,LIST                          !列表查看特征值

/GFORMAT,F,12,3,          !數據格式

/DSCALE,ALL,30             !變形比例

PLNSOL, U,SUM, 0,1.0    !屈曲變形

轉載自好學ANSYS公眾號，具體操作過程，請移步至公眾號哦~這里是鏈接：https://mp.weixin.qq.com/s/uvsEt4sW1KQXiAh_9fF2dg