一、實物模型演示

一個單獨的鋼尺和一個由兩個相同的鋼尺栓接在一起的組合鋼尺，如圖1(1)所示，以懸臂的形式并排在一起。對這兩個鋼尺的懸臂端施加相同的初位移，然后同時迅速釋放，使之產生自由振動。可以發現，由兩塊組合的鋼尺要比單塊鋼尺更快停止振動，見如圖1(2)。

  (1) 施加相同的初始位移

(2)兩塊組合的鋼尺要比單塊鋼尺更快停止振動

圖1  自由振動衰減與結構固有頻率的關系

本模型演示表明，結構的固有頻率越高，其自由振動衰減越快。

二、問題描述

假設鋼板尺子的長度L= 0.5 m，寬度h = 40mm，厚度b = 2 mm。彈性模量E = 200 GPa，泊松比u= 0.3，密度 7800 kg/m³。分別計算單獨的鋼尺和組合鋼尺的振動情況。

---

三、問題分析

一端用壓在桌子上，可處理成固定端，約束可處理成全固定。懸臂端施加相同的初位移，然后松手釋放，約束可處理成自由邊界。

由此可見，振幅對數衰減率僅取決于阻尼比。本算例初始的振幅相同，振幅對數衰減率也一樣，但是組合鋼尺的固有頻率是單塊鋼尺的2倍，組合鋼尺振動快一些，其自由振動的衰減也就快一些。因此，從理論上證實前面的概念：結構的固有頻率越高，其自由振動的衰減越快。

在ANSYS計算中，不是直接輸入阻尼比。而是通過對數衰減率δ、阻尼系數c、α質量阻尼或者β剛度阻尼等方式輸入的。本算例考慮阻尼，采用振幅對數衰減率輸入。下表給出了兩種結構的固有頻率、周期和振幅對數衰減率。

ANSYS分析主要步驟：

（1）建模，進行模態分析，求出固有頻率。

（2）在懸臂端施加集中力，進行靜力學分析。得到各節點的初位移數值，初位移包括初始撓度和初始轉角。

（3）進行瞬態動力學分析，施加振幅對數衰減率。在第1載荷步，關閉時間積分影響，施加初位移；第2載荷步，時間積分時間增量取一個周期的1/60，保存每個子步的結果進行求解。在時間歷程后處理中，得到的撓度隨時間變化曲線見圖3。

由此可見，組合鋼尺的振動周期的時間短固有頻率高，組合鋼尺比單個鋼尺衰減得更快一些。

圖3 撓度隨時間變化

---

四、命令流

Ex1=2e11      !彈性模量Pa

b1=1*3e-3     !截面寬度m，修改此處b1=2*3e-3

h1=40e-3      !截面長度m

L1=0.5        !長度m

rou1=7800     !密度

m1=b1*h1*rou1 !單位長度的質量

 

I1=h1*b1**3/12      !慣性矩

pi=acos(-1)

k1=(Ex1*I1/(m1*L1**4))**0.5

Fre0=3.516/(2*pi)*k1  !第1階固有頻率解析解Hz

T0=1/Fre0           !第1階固有周期s

 

kesi=0.02     !阻尼比或相對阻尼系數0.02

Fre1=Fre0/(1-kesi)**0.5 !有阻尼條件下第1階固有頻率

T1=1/Fre1     !有阻尼條件下第1階固有周期s

 

!c1=2*kesi*m1*L1*(2*pi*Fre1)  !阻尼系數，好像有問題

afa1=2*kesi*(2*pi*Fre1)

 

uy1=0.05               !假定的初位移

F1=3*Ex1*I1*uy1/L1**3  !懸臂梁已知初位移求載荷

 

/PREP7

ET,1,BEAM188  !單元類型

KEYOPT,1,3,3   !形函數

MP,EX,1,Ex1    !材料屬性Pa

MP,PRXY,1,0.3

MP,DENS,1,rou1

!MP,DMPR,1,kesi           !阻尼比

SECTYPE,1,BEAM,RECT,,0  !截面屬性m

SECOFFSET,CENT

SECDATA,b1,h1

K,1,0,0,0         !關鍵點mm

K,2,L1,0,0

L,1,2            !線

/PNUM,KP,1     !關鍵點編號

/PNUM,LINE,1   !線編號

LATT,1,,1,,,,1    !線的單元屬性

LESIZE,all,,,20 !單元份數

LMESH,ALL    !線分網

/ESHAPE,1.0    !單元形狀

DK,1,ALL       !施加位移約束

FINISH

/SOLU

ANTYPE,2      !模態分析

MODOPT,LANB,6

MODOPT,LANB,6,0,0,,OFF

SOLVE

FINISH

/POST1

SET,LIST

fre=Fre1

/SOLU

ANTYPE,0    !靜力求解

FK,2,FY,-F1   !集中力N

SOLVE       !求解

FINISH

/POST1

*DIM,uyy,ARRAY,21,3,1   !數組

*do,i,1,21

 uyy(i,1)=i      !節點號

 uyy(i,2)=uy(i)   !撓度

 uyy(i,3)=rotz(i)  !轉角

*enddo

FINISH

/SOLU

ANTYPE,4     !瞬態動力學

TRNOPT,FULL

TIMINT,ON

delta=2*pi*kesi/(1-kesi**2)**0.5      !對數衰減率

GAMMA=delta

TINTP,GAMMA

TIMINT,OFF   !時間積分影響關閉

TIME,1e-6     !小的時間增量

NSUBST,2     !兩個載荷步

KBC,1         !階躍

FKDELE,2,FY   !刪除載荷

*do,i,1,21

D,uyy(i,1),UY,uyy(i,2)    !施加初位移

D,uyy(i,1),ROTZ,uyy(i,3)

*enddo

SOLVE        !求解

TIMINT,1      !打開時間積分影響

DELTIM,1/fre1/60,0,0  !時間增量，一個周期計算60次

OUTRES,ALL,1      !輸出每步的結果

DDELE,ALL,all    !刪除初位移約束

D,1,all            !施加固定端約束

KBC,0            !斜坡

TIME,20*1/fre1    !計算時間20個周期

TIME,4           !計算時間4s

!ALPHAD,afa1

SOLVE           !求解

FINISH

/POST26          !時間歷程后處理

FILE,'file','rst','.'

NSOL,2,2,U,Y,

XVAR,1

/YRANGE,-uy1,uy1,1

PLVAR,2,    !撓度曲線

轉載自好學ANSYSA。詳細模型及文件請移步公眾號~鏈接：https://mp.weixin.qq.com/s/EO_StXY70wSSMDNraOc3Gg