ANSYS中螺旋箍筋的建模

近日，有不少同學向水哥咨詢螺旋箍筋的相關問題，今天終于忙里偷閑，得一閑暇下午，趁空與大家分享下ANSYS中螺旋箍筋的建模方法。

        螺旋箍筋可以分為矩形螺旋箍筋以及圓環螺旋箍筋，兩者建模思路一樣，相對來講，圓環螺旋箍筋建模會稍微比較繁瑣一點，這里水哥就以圓環螺旋箍筋建模為例，說說其建模方法。

        本文案例如下：

        某圓柱，直徑1000，長度2550，采用C40混凝土，HRB400鋼筋，配置螺旋箍筋，間距為150，保護層厚度為50，試采用ANSYS建立該柱有限元模型。結構幾何模型如下：

        建模思路以及注意的幾個關鍵點：

一、總體建模思路與常見的通過劃分幾何線形成鋼筋單元不同，螺旋鋼筋建模通過節點建立單元的方式形成鋼筋單元。

二、建模坐標系為柱坐標系。

三、確定每一半圈鋼筋的劃分段數，并根據劃分段數確定整體模型的豎向劃分段數。

四、定義數組，通過位置坐標獲取在特定位置處的節點編號，存入數組。

五、建立相應的鋼筋單元。

        螺旋箍筋的建模需要一定的編程基礎，限于篇幅，本次僅僅羅列出關鍵地方的命令流，并進行一定的講解。

！========

finish

/clear

/prep7

et,1,solid65

et,2,link8

!==========

材料、實常數定義

!===========

!建立外圈混凝土，并切分出縱筋線

cyl4,,,450,,500,360,2550

wprota,,,90

*do,i,1,10

wprota,,18

vsbw,all

*enddo

wpcsys,-1

!==============

!按照150距離內切分為10份的方法切割出輪廓

!保證后續劃分網格時在我們需要的位置有結點

wpoffs,,,150

vsbw,all

wpoffs,,,150

vsbw,all

*do,i,1,13

*do,j,1,10

wpoffs,,,15

vsbw,all

*enddo

vsel,u,loc,z,0,150*i+300

*enddo

wpoffs,,,150

vsbw,all

wpcsys,-1

allsel,all

!============

!建立內部混凝土柱，并進行布爾運算

cyl4,,,,,450,360,2550

vglue,all

!============

!=============

!選擇端部箍筋線，劃分網格

csys,1

lsel,s,loc,z,150

lsel,a,loc,z,2400

lsel,r,loc,x,450

latt,2,2,2

lesize,all,15

lmesh,all

!===================

!選擇縱筋線，劃分網格

csys,1

lsel,s,loc,y,0

*do,i,1,19

lsel,a,loc,y,18*i

*enddo

lsel,r,loc,x,450

latt,2,3,2

lesize,all,15

lmesh,all

!==================

!進行體劃分

vatt,1,1,1

esize,15

vsweep,all

!==================

!本文之精華所在

!獲取各個特定位置處的箍筋結點編號，并存入數組

csys,1

*dim,nodeA,array,,121

kk=0

*do,j,1,6

*do,i,1,20

xx=450

YY=18*(i-1)

zz=300+15*(i-1)+300*(j-1)

kk=kk+1

nodenum=node(xx,yy,zz)

nodeA(1,kk)=nodenum

*enddo

*enddo

*do,i,1,11

xx=450

YY=18*(i-1)

zz=300+15*(i-1)+300*6

kk=kk+1

nodenum=node(xx,yy,zz)

nodeA(1,kk)=nodenum

*enddo

!============

type,2 

mat,2 

real,2

*do,i,1,130

e,nodeA(1,i),nodeA(1,i+1)

*enddo

螺旋箍筋效果如下：

        矩形螺旋箍筋建模和本文思路如出一轍，這里就不在演示了

歡迎關注微信公眾號：ANSYSABAQUS