rou 0.1

SET edge 0.4

;巖層劃分/細(xì)分

blo 0,0 0,90 200,90 200,0

;底板基巖（中粒砂巖15m）

cr 0,0 200,0

cr 0,15 200,15

;底板老底（粉砂巖2m）

cr 0,17 200,17

;底板直接底（泥巖2m）

cr 0,19 200,19

;煤層（煤厚5m）

cr 0,24 200,24

;直接頂（泥巖2m）

cr 0,26 200,26

;老頂（粉砂巖6m）

cr 0,32 200,32

;粉砂巖5m

cr 0,37 200,37

;細(xì)粒砂巖5m

cr 0,42 200,42

;砂質(zhì)泥巖6m

cr 0,48 200,48

;細(xì)粒砂巖6m

cr 0,54 200,54

;砂質(zhì)泥巖36m

cr 0,90 200,90

def wa

     xx1=40

loop i (1,41)

      command

       cr xx1,19 xx1 24

   end_command

      xx1=xx1+3

end_loop

end

wa

;節(jié)理塊劃分

;底板基巖(15m)

jreg id 1 0,0 0,15 200,15 200,0              ;四個點圈成一個區(qū)域

jset 0,0 200,0 0,0 5,0 0,5 range jreg 1      ;jset 傾角0度,0 線段長200,0 線段與線段軸向間隔長0,0 垂向間距3,0 xm,ym range jregion n，其中xm,ym為起始點（0，0）坐標(biāo),n為設(shè)置的區(qū)域標(biāo)號

jset 90,0 5,0 5,0 10,0 10,0 range jreg 1     ;jset 傾角90度,0 線段長3,0 線段與線段軸向間隔長3,0 垂向間距10,0 xm,ym range jregion n，其中xm,ym為起始點（10，0），線段有兩組，兩組之間的距離是3米

jset 90,0 5,0 5,0 10,0 5,5 range jreg 1      ;jset 傾角90度,0 線段長3,0 線段與線段軸向間隔長3,0 垂向間距10,0 xm,ym range jregion n，其中xm,ym為起始點（5，3）

;老底（2m）

jreg id 2 0,15 0,17 200,17 200,15

jset 90,0 2,0 0,0 2,0 1,15 range jreg 2

;直接底（泥巖2m）

jreg id 3 0,17 0,19 200,19 200,17

jset 90,0 2,0 0,0 2,0 2,17 range jreg 3

;煤（5m）

jreg id 4 0,19 0,24 200,24 200,19

jset 0,0 200,0 0,0 1,0 0,20 range jreg 4

jset 90,0 1,0 1,0 2,0 2,19 range jreg 4

jset 90,0 1,0 1,0 2,0 1,20 range jreg 4

;直接頂（2m）

jreg id 5 0,24 0,26 200,26 200,24

jset 0,0 200,0 0,0 1,0 0,25 range jreg 5

jset 90,0 1,0 1,0 2,0 2,25 range jreg 5

jset 90,0 1,0 1,0 2,0 1,24 range jreg 5

;老頂（6m）

jreg id 6 0,26 0,32 200,32 200,26

jset 0,0 200,0 0,0 2,0 0,28 range jreg 6

jset 90,0 2,0 2,0 3,0 3,26 range jreg 6

jset 90,0 2,0 2,0 3,0 1.5,28 range jreg 6

;粉砂巖（5m）

jreg id 7 0,32 0,37 200,37 200,32

jset 0,0 200,0 0,0 2.5,0 0,32 range jreg 7

jset 90,0 2.5,0 2.5,0 3,0 1.5,32 range jreg 7

jset 90,0 2.5,0 2.5,0 3,0 3,34.5 range jreg 7

;細(xì)粒砂巖（5m）

jreg id 8 0,37 0,42 200,42 200,37

jset 0,0 200,0 0,0 2.5,0 0,37 range jreg 8

jset 90,0 2.5,0 2.5,0 3,0 1.5,37 range jreg 8

jset 90,0 2.5,0 2.5,0 3,0 3,39.5 range jreg 8

;砂質(zhì)泥巖（6m）

jreg id 9 0,42 0,48 200,48 200,42

jset 0,0 200,0 0,0 3,0 0,42 range jreg 9

jset 90,0 3,0 3,0 5,0 5,42 range jreg 9

jset 90,0 3,0 3,0 5,0 2.5,45 range jreg 9

;細(xì)粒砂巖（6m）

jreg id 10 0,48 0,54 200,54 200,48

jset 90,0 6,0 0,0 7.5,0 7.5,48 range jreg 10

;砂質(zhì)泥巖（36m）

jreg id 11 0,54 0,90 200,90 200,54

jset 0,0 200,0 0,0 6,0 0,60 range jreg 11

jset 90,0 6,0 6,0 10,0 10,54 range jreg 11

jset 90,0 6,0 6,0 10,0 5,60 range jreg 11

del range area 0.01                      ;刪除面積小于0.01的范圍

gen edge 2                               ;劃分最小單元的尺寸

sav mode.sav

change cons 3                       ;選擇摩爾-庫侖本構(gòu)模型，CHANGE 命令改變塊體為指定的變形塊體。

change mat 1 range 0,200 0,15        ;中砂巖，材料號再賦給具有CHANGE mat 命令的塊體。

change mat 2 range 0,200 15,17       ;底板老底粉砂巖

change mat 3 range 0,200 17,19       ;直接底泥巖

change mat 4 range 0,200 19,24       ;13-1煤

change mat 3 range 0,200 24,26       ;頂板直接頂泥巖

change mat 2 range 0,200 26,32       ;頂板老頂粉砂巖

change mat 2 range 0,200 32,37       ;粉砂巖

change mat 5 range 0,200 37,42       ;細(xì)砂巖

change mat 6 range 0,200 42,48       ;砂質(zhì)泥巖

change mat 5 range 0,200 48,54       ;細(xì)砂巖

change mat 6 range 0,200 54,90       ;砂質(zhì)泥巖

prop mat 1 d=2550 bulk=26.23e9 shear=9.4e9 fric=34 coh=23.13e6 ten=0

prop mat 2 d=2450 bulk=12.2e9 shear=9.92e9 fric=31 coh=17.64e6 ten=0

prop mat 3 d=2500 bulk=14.17e9 shear=5.43e9 fric=35 coh=8.25e6 ten=0

prop mat 4 d=13500 bulk=4.31e9 shear=0.73e9 fric=36 coh=2.96e6 ten=0

prop mat 5 d=2500 bulk=16.67e9 shear=7.69e9 fric=35 coh=20.8e6 ten=0

prop mat 6 d=2430 bulk=13.57e9 shear=6.26e9 fric=30 coh=13.4e6 ten=0

change jcons 5                      ;指定庫侖滑動模型（完全彈塑性）

set jcondf=5

change jmat=1 range 0,200 0,15

change jmat=2 range 0,200 15,17

change jmat=2 range 0,200 26,37

change jmat=3 range 0,200 17,19

change jmat=3 range 0,200 24,26

change jmat=4 range 0,200 19,24

change jmat=5 range 0,200 37,42

change jmat=5 range 0,200 48,54

change jmat=6 range 0,200 42,48

change jmat=6 range 0,200 54,90

prop jmat=1 jkn=5e11 jks=20e11 jcoh=1.0e6 jfr=25 jten=0           ;中細(xì)砂巖

prop jmat=2 jkn=5e11 jks=5e11 jcoh=1.0e6 jfr=35  jten=0          ;粉砂巖，節(jié)理的切向剛度和法向剛度，節(jié)理面的摩擦角

prop jmat=3 jkn=2e11 jks=2e11 jcoh=1.0e6 jfr=30  jten=0          ;泥巖

prop jmat=4 jkn=1e11 jks=1e11 jcoh=1.0e6 jfr=15  jten=0          ;煤

prop jmat=5 jkn=5e11 jks=5e11 jcoh=1.0e6 jfr=25  jten=0          ;中細(xì)砂巖

prop jmat=6 jkn=5e11 jks=5e11 jcoh=1.0e6 jfr=25  jten=0          ;中細(xì)砂巖

set grav 0 -10

insitu stress -10e6,0,-10e6 szz -10e6                    ;在x方向始化所有的應(yīng)力為-15MPa和在y方向初始化應(yīng)力為-7.5MPa。在平面之外的z方向也給予初值 =-7.5MPa。

bound stress 0,0,-10e6 range -0.1,200.1 89.9 90.1         ;固定最上面一個面

bound stress -10e6,0,0 range -0.1,0.1 -0.1 90.1          ;固定最左邊的一個面

bound stress -10e6,0,0 range 199.9,200.1 -0.1 90.1       ;固定最右邊的一個面

bound yvel=0.0 range yran -0.1 0.1                       ;固定最底面y方向的速率

bound xvel=0.0 range xran -0.1 0.1                       ;固定最左邊一個面x方向的速率

bound xvel=0.0 range xran 199.9,200.1                      ;固定最右邊一個面x方向的速率

damp auto                                                ;重力加載于彈性系統(tǒng)，采用目標(biāo)阻尼（DAMP auto）以提供快速平衡求解。

hist solve_rat type 1

hist unbal

solve rat 1e-5

save 1305cs.sav

reset disp jdisp

reset hist

hist unbal

hist ydis 22.4,24

hist ydis 22.4,26

hist ydis 51.2,24

hist ydis 51.2,26

hist syy 22.4,24

hist syy 22.4,26

hist syy 51.2,24

hist syy 51.2,26

hist sxx 20,22

hist sxx 20,22

hist sxx 80,22

hist sxx 80,22

def kaiwa1

    xx1=40

yy1=19

yy2=24

loop i(1,40)

         xx2=xx1+3

   command

       dele range xx1,xx2 yy1,yy2

    damp  auto

             STEP 120

   end_command

   xx1=xx2

end_loop

end

kaiwa1

save 1305kw1.sav