/PREP7 !進入前處理器
!define element type 定義元素類型（95）和材料特性
ET,1,PIPE16 !定義單元類型，編號為1的pipe16，管模型用
ET,2,MASS21 !定義單元類型，編號為2的mass21，質量點用
!*
R,1,D1,T1,,,,, !定義單元實常數，第1組值D1、T1
RMORE,,,,,,, !添加實常數到一個常數集中。此命令在此可刪除。
RMORE,,
!*
R,2,D2,T2,,,,, !定義單元實常數，第2組值D2、T2
RMORE,,,,,,, !添加實常數
RMORE,,
!*
R,3,D3,T3,,,,,
RMORE,,,,,,,
RMORE,,
!*
R,4,1.1*D1,2*T1,,,,, !定義單元實常數，第4組，值為1.1*D1、2*T1
RMORE,,,,,,,
RMORE,,
R,5,le-5,,,,,, !定義第5組單元實常數，值為le-5。
UIMP,1,EX,,,EX_1, !定義彈性模量值為EX-1所代表的值
UIMP,1,PRXY,,,PRXY_1, !主泊松比為PRXY-1所代表的值
UIMP,1,ALPX,,,, !輸入一個常數值的熱膨脹系數
UIMP,1,REFT,,,, !定義參考溫度
UIMP,1,MU,,,, !定義摩擦因數
UIMP,1,DAMP,,,, !用于阻尼的K矩陣乘子
UIMP,1,DENS,,,DENS_1, !質量密度值為DENS-1所代表的值
!*
!----------------------以下建臂架----
!Begin to creat crank jab
!開始建立臂架
!
!Define KPoint 生成關鍵點
!畫直線與鏡像，拷貝
K,1,L2/2,L3/2,0, !KP1,主弦桿起點坐標點（L2/2,L3/2,0）
K,2,L2/2,L3/2,L1, !KP2,主弦桿終點坐標點（L2/2,L3/2,L）
LSTR,1,2 !生成第一根主弦桿
LSYMM,Y,ALL,,,,0,0 !鏡像拷貝主弦管，關于Y軸對稱，生成節點和控制鍵，同時保留原來關鍵點
LSYMM,X,ALL,,,,0,0 !鏡像拷貝主弦管，關于X軸對稱，生成節點和控制鍵，同時保留原來關鍵點
!-------------生成主弦桿----
KWPAVE,1 !移動工作平面到編號為1的關鍵點
wpoff,0,0,L4 !相對當前點移動工作平面，移動距離分別為0,0，L4
LSBW,all !用工作平面分割所有的線
*do,i,1,N,1 !進入do循環
wpoff,0,0,AA(i) !相對當前點移動工作平面，移動距離為0,0，AA（i）
LSBW,all !分割所有線
*enddo
!--------------生成第一組斜向腹桿----
WPCSYS,-1,0 !將工作平面與整體坐標相對應
LSTR,kp(L2/2,-L3/2,L4),kp(-L2/2,-L3/2,L4) !生成線，在此坐標下，生成的是垂線
LK=L4
wpoff,0,0,LK ! 相對當前點移動工作平面，移動距離為0,0，Lk
CSYS,4 !指定工作平面
*do,i,0,N-1,1
*if,i,eq,0,then !if循環，如果i=0，那么執行下一條語句
LSTR,kp(L2/2,-L3/2,0),kp(-L2/2,-L3/2,AA(1))
*else
wpoff,0,0,AA(i)
LSTR,kp((-1)**(i)*L2/2,-L3/2,0),kp((-1)**(i+1)*L2/2,-L3/2,AA(i+1))
*endif !結束if循環
*enddo
LSTR,kp(L2/2,-L3/2,AA(i+1)),kp(-L2/2,-L3/2,AA(i+1)) !生成線，也是垂線
!--------------生成第二組斜向腹桿----
WPCSYS,-1,0
LSTR,kp(L2/2,L3/2,L4),kp(-L2/2,L3/2,L4)
LK=L4
wpoff,0,0,LK
CSYS,4
*do,i,0,N-1,1
*if,i,eq,0,then
LSTR,kp(-L2/2,L3/2,0),kp(L2/2,L3/2,AA(1))
*else
wpoff,0,0,AA(i)
LSTR,kp((-1)**(i+1)*L2/2,L3/2,0),kp((-1)**(i)*L2/2,L3/2,AA(i+1))
*endif
*enddo
LSTR,kp(L2/2,L3/2,AA(i+1)),kp(-L2/2,L3/2,AA(i+1))
!---------------生成第三組斜向腹桿----
WPCSYS,-1,0
LSTR,kp(L2/2,L3/2,L4),kp(L2/2,-L3/2,L4)
LK=L4
wpoff,0,0,LK
CSYS,4
*do,i,0,N-1,1
*if,i,eq,0,then
LSTR,kp(L2/2,-L3/2,0),kp(L2/2,L3/2,AA(1))
*else
wpoff,0,0,AA(i)
LSTR,kp(L2/2,(-1)**(i+1)*L3/2,0),kp(L2/2,(-1)**(i)*L3/2,AA(i+1))
*endif
*enddo
LSTR,kp(L2/2,-L3/2,AA(i+1)),kp(L2/2,L3/2,AA(i+1))
!---------------生成第四組斜向腹桿----
WPCSYS,-1,0
LSTR,kp(-L2/2,L3/2,L4),kp(-L2/2,-L3/2,L4)
LK=L4
wpoff,0,0,LK
CSYS,4
*do,i,0,N-1,1
*if,i,eq,0,then
LSTR,kp(-L2/2,L3/2,0),kp(-L2/2,-L3/2,AA(1))
*else
wpoff,0,0,AA(i)
LSTR,kp(-L2/2,(-1)**(i)*L3/2,0),kp(-L2/2,(-1)**(i+1)*L3/2,AA(i+1))
*endif
*enddo
LSTR,kp(-L2/2,-L3/2,AA(i+1)),kp(-L2/2,L3/2,AA(i+1))
!---------------生成兩斷面斜向腹桿----
WPCSYS,-1,0
LSTR,kp(-L2/2,-L3/2,L4),kp(L2/2,L3/2,L4)
line_11=_return !返回這條線的編號
LSTR,kp(L2/2,-L3/2,L1-L4),kp(-L2/2,L3/2,L1-L4)
line_12=_return
!---------------定義斜向腹桿屬性----
CSYS,0 !指定直角坐標系
LPLOT !顯示線
ALLSEL,ALL !選擇所有實體
LSEL,S,LOC,Y,-0.5*L3/2,0.5*L3/2 !選擇有效線段，從數據集中選擇，Y坐標介于-0.5*L3/2至0.5*L3/2
LSEL,A,LOC,X,-0.5*L2/2,0.5*L2/2 !選擇有效線段，從數據集中再選擇部分數據添加到選擇集中，X坐標介于-0.5*L2/2至0.5*L2/2

ALLSEL,BELOW,LINE !選擇直接相關的線實體
!*
LATT,1,2,1,,,, ! 定義各種元素類型
!---------------定義主弦桿屬性----
CM,FUGAN,LINE !由所選擇的實體生成一個實體，線實體名為FUGAN
ALLSEL,ALL
CMSEL,U,FUGAN !選擇從整體中減去ＦＵＧＡＮ的剩余部分實體
LATT,1,1,1,,,,
ALLSEL,ALL　　　　!選擇所有實體
LPLOT　　　　　　!顯示線
!---------------定義垂向腹桿屬性----
ALLSEL,ALL
LPLOT
LSEL,S,LOC,Z,L4　　　　!從實數集中選擇Ｚ坐標為Ｌ４的有效線段
LSEL,A,LOC,Z,L1-L4 !
LSEL,U,,,line_11　　!從所選擇線中減去line_11所代表的線
LSEL,U,,,line_12　　!從所選擇線中減去line_12所代表的線
ALLSEL,BELOW,LINE!*
LATT,1,3,1,,,,
ALLSEL,ALL
!-------定義接頭屬性----
ALLSEL,ALL
LPLOT
LSEL,S,LOC,Z,0,L4
LSEL,A,LOC,Z,L1-L4,L1
LSEL,U,LOC,Z,L4
LSEL,U,LOC,Z,L1-L4
ALLSEL,BELOW,LINE
!*
LATT,1,4,1,,,,
ALLSEL,ALL
!---------------畫網格----
ALLSEL,ALL
ESIZE,5*D1,0, !定義要劃分的單元邊長和分段數，單元邊數為5*D1，段數為0

LMESH,ALL !網格化所有實體
/ESHAPE,1.0 !根據實常數1.0來確定單元的顯示
NUMMRG,ALL,,,,LOW !合并所有實體，保留低編號項
/REPLOT !刷新顯示實體
ALLSEL,ALL
SAVE,, !保存
CDWRITE,ALL,,'cdb',,,'iges' !寫模型