本人自己編寫的APDL語言進行齒輪建模，歡迎大家指正。
!第一步 初始化ansys環境
finish
/CLEAR
/BATCH
/TITLE,The Process of creating Gear Parametric Modeling
!第二步 定義幾何尺寸參數
!MULTIPRO,'START',5 !通過多參數輸入對話框進行賦值
!*cset,1,3,z,'Number of teeth;',52 !齒數
!*cset,4,6,m,'Model number(mm);',5 !模數
!*cset,7,9,b,'Tooth width(mm);',15 !齒寬
!*cset,10,12,ha,'Addendum coefficient(mm);',1 !齒頂高系數
!*cset,13,15,c,'Headspace coefficient(mm);',0.25 !頂隙系數
!MULTIPRO,'end'
!*IF,_BUTTON,EQ,1,THEN
!/EOF
!*ENDIF
z=52
m=5
b=15
ha=1
c=0.25
ang=360/z !每齒的圓心角
rf=(z-2*ha-2*c)*m/2 !齒根圓半徑
ra=(z+2*ha)*m/2 !齒頂圓半徑
r1=m*c !齒根圓倒角半徑
rb=m*z*cos(3.14159/9)/2
inva=0.014904 !漸開線函數值
*AFUN,RAD
pi=Acos(-1)
*DIM,X,,22 !定義兩個數組用來定義生成的點
*DIM,Y,,22
af=Acos(rb/rf)
invaf=tan(af)-af
Gamaf=pi/(2*z)-(invaf-inva) !計算齒根圓齒厚對應的圓心角
x(1)=rf*cos(Gamaf) !計算齒根圓坐標值
y(1)=rf*sin(Gamaf)
*DO,i,1,11
!ri=rf+r1+i-1
ri= rf+r1+(ra-(rf+r1))*(i-1)/10
i=i+1
ai=Acos(rb/ri) !計算任意圓對應的壓力角
invai=tan(ai)-ai
Gamai=pi/(2*z)-(invai-inva) !任意圓對應齒厚圓心角
x(i)=ri*cos(Gamai)
y(i)=ri*sin(Gamai)
*ENDDO
!第三步 利用參數創建幾何模型
/PREP7
*DO,i,1,12 !生成漸開線齒廓上的關鍵點
K,i,x(i),y(i)
*ENDDO
K,13,ra,0 !生成齒頂圓上的關鍵點
BSPLN,12,13 !連線生成齒頂圓
BSPLN,12,11,10,9,8,7 !樣條擬合生成齒廓
BSPLN,7,6,5,4,3,2
BSPLN,2,1
LCOMB,2,3,0
LCOMB,2,4,0 !由幾段樣條生成一條齒廓
CYL4,,,108.75,0,rf,ang/2 !生成一個圓環
ADELE,1 !刪除生成的圓環面
LDELE,3 !刪除一條與齒廓相連的線
LSTR,7,1
LSTR,2,13
LFILLT,2,3,r1,, !對齒根圓進行倒角
AL,ALL !形成一個齒形面
!下面對生成的網格和面通過鏡像復制方式
WPCSYS,-1,0 !工作平面恢復到總體坐標系的原點
CSYS,4 !激活當前坐標系為工作平面坐標系
ARSYM,Y,ALL,,,,0,0
CSYS,1 !激活當前坐標系為柱坐標系
CM,GEAR1,AREA !創建面組：包含齒形面
AGEN,52,GEAR1,,,,ANG,,,0 !繞Y軸旋轉復制生成3個齒形面
AADD,ALL !所有面相加
!下面對生成的三個齒形面進行拉伸
WPCSYS,-1,0 !工作平面恢復到總體坐標系的原點
CSYS,4
CM,GEAR2,AREA !創建面組：包含所有創建的面
VEXT,GEAR2,,,0,0,b,, !拉伸面組，生成實體
/VIEW,1,1,1,-1 !改變視角
!第四步 劃分單元網格模型
ET,1,SOLID186 !定義單元類型
MSHAPE,1,3d !指定為3D結構
CM,VGEAR,VOLU !創建實體組：包含所有創建的實體
VMESH,VGEAR
SAVE