!下面的命令流進(jìn)行的是一個(gè)簡(jiǎn)單的二維焊接分析, 利用 ANSYS單元生死和熱-結(jié)構(gòu)耦合分析功能進(jìn)
!行焊接過(guò)程仿真, 計(jì)算焊接過(guò)程中的溫度分布和應(yīng)力分布以及冷卻后的焊縫殘余應(yīng)力。
finish
/clear
/filnam,1-2D element birth and death
/title,Weld Analysis by "Element Birth and Death"
/prep7
/unit,si !采用國(guó)際單位制
!******************************************************
et,1,13,4 !13號(hào)二維耦合單元, 同時(shí)具有溫度和位移自由度
et,2,13,4
!1號(hào)材料是鋼
!2號(hào)材料是鋁
!3號(hào)材料是銅
!鋁是本次分析中的焊料, 它將鋼結(jié)構(gòu)部分和銅結(jié)構(gòu)部分焊接起來(lái)
!下面是在幾個(gè)溫度點(diǎn)下, 各材料的彈性模量
mptemp,1,20,500,1000,1500,2000
mpdata,ex,1,1,1.93e11,1.50e11,0.70e11,0.10e11,0.01e11
mpdata,ex,2,1,1.02e11,0.50e11,0.08e11,0.001e11,0.0001e11
mpdata,ex,3,1,1.17e11,0.90e11,0.30e11,0.05e11,0.005e11
!假設(shè)各材料都是雙線性隨動(dòng)硬化彈塑性本構(gòu)關(guān)系
!下面是各材料在各溫度點(diǎn)下的屈服應(yīng)力和屈服后的彈性模量
tb,bkin,1,5
tbtemp,20,1
tbdata,1,1200e6,0.193e11
tbtemp,500,2
tbdata,1, 933e6,0.150e11
tbtemp,1000,3
tbdata,1, 435e6,0.070e11
tbtemp,1500,4
tbdata,1, 70e6,0.010e11
tbtemp,2000,5
tbdata,1, 7e6,0.001e11
!
tb,bkin,2,5
tbtemp,20,1
tbdata,1,800e6,0.102e11
tbtemp,500,2
tbdata,1,400e6,0.050e11
tbtemp,1000,3
tbdata,1, 70e6,0.008e11
tbtemp,1500,4
tbdata,1, 1e6,0.0001e11
tbtemp,2000,5
tbdata,1,0.1e6,0.00001e11
!
tb,bkin,3,5
tbtemp,20,1
tbdata,1,900e6,0.117e11
tbtemp,500,2
tbdata,1,700e6,0.090e11
tbtemp,1000,3
tbdata,1,230e6,0.030e11
tbtemp,1500,4
tbdata,1, 40e6,0.005e11
tbtemp,2000,5
tbdata,1, 4e6,0.0005e11
!
!材料密度(假設(shè)為常值)
mp,dens,1,8030
mp,dens,2,4850
mp,dens,3,8900
! 熱膨脹系數(shù)(假設(shè)為常值)
mp,alpx,1,1.78e-5
mp,alpx,2,9.36e-6
mp,alpx,3,1.66e-5
!泊松比(假設(shè)為常值)
mp,nuxy,1,0.29
mp,nuxy,2,0.30
mp,nuxy,3,0.30
!熱傳導(dǎo)系數(shù)(假設(shè)為常值)
mp,kxx,1,16.3
mp,kxx,2,7.44
mp,kxx,3,393
!比熱(假設(shè)為常值)
mp,c,1,502
mp,c,2,544
mp,c,3,385
!熱膨脹系數(shù)(假設(shè)為常值)
!由于該13號(hào)單元還有磁自由度, 此處假設(shè)一磁特性, 但并不影響我們所關(guān)心的結(jié)果
mp,murx,1,1
mp,murx,2,1
mp,murx,3,1
!假設(shè)焊料(鋁)焊上去后的初始溫度是1500℃
mp,reft,1,20
mp,reft,2,1500
mp,reft,3,20
!******************************************************
!下面建立幾何模型
csys,0
k,1,0,0,0
k,2,0.5,0,0
k,3,1,0,0 !長(zhǎng)1米
k,4,0,0.3,0 !厚度0.3米（二維中叫做寬度）
k,5,0.35,0.3,0
k,6,0.65,0.3,0
k,7,1,0.3,0
a,1,2,5,4
a,2,6,5
a,2,3,7,6
!!!!!!!!!!!!!!!!!!!!!!!!!!劃分網(wǎng)格!!!!!!!!!!!!!!!!!
esize,0.025
type,2
mat,2
amesh,2
!
esize,0.05 !網(wǎng)格劃分出現(xiàn)問(wèn)題
type,1
mat,1
amesh,1
!
mat,3
amesh,3
eplot
!
/solu
antype,4 ! 瞬態(tài)分析
trnopt,full
!!!!!!!!!!!!!!!!!!!!!!!!在模型的左邊界加位移約束!!!!!!!!!!!!!!!!!!!!!!!!!!!
nsel,all
*get,minx,node,,mnloc,x
nsel,s,loc,x,minx
d,all,ux,0
*get,miny,node,,mnloc,y
nsel,r,loc,y,miny
d,all,uy,0
!*****假設(shè)模型的左右邊界處溫度始終保持在20攝氏度左右*****
!其他邊界條件如對(duì)流和輻射等均可施加，此處因?yàn)橹皇鞘疽舛眩手皇┘雍銣剡吔鐥l件
nsel,all
*get,minx,node,,mnloc,x
nsel,s,loc,x,minx
d,all,temp,20
nsel,all
*get,maxx,node,,mxloc,x
nsel,s,loc,x,maxx
d,all,temp,20
!!!!!!!!!!!!!!!由于第2個(gè)面是焊接所在區(qū)域，因此首先將該區(qū)域的單元“殺死”!!!!!!!!!!!!!!!!
nna=2
esel,all
*get,emax,elem,,num,max
asel,s,area,,nna
esla
*get,nse,elem,,count
*dim,ne,,nse
*dim,nex,,nse
*dim,ney,,nse
*dim,neorder,,nse
mine=0
!**********************************************
!下面的do循環(huán)用于將焊料區(qū)的單元按其形心y坐標(biāo)排序
!以便后面模擬焊料由下向上逐步“生長(zhǎng)”過(guò)程
*do,i1,1,nse
esel,u,elem,,mine
*get,nse1,elem,,count
ii=0
*do,i,1,emax
*if,esel(i),eq,1,then
ii=ii+1
ne(ii)=i
*endif
*enddo
*do,i,1,nse1
*get,ney(i),elem,ne(i),cent,y
*get,nex(i),elem,ne(i),cent,x
*enddo
miny=1e20
minx=1e20
*do,i,1,nse1
*if,ney(i),lt,miny,then
miny=ney(i)
minx=nex(i)
mine=ne(i)
*else
*if,ney(i),eq,miny,then
*if,nex(i),lt,minx,then
miny=ney(i)
minx=nex(i)
mine=ne(i)
*endif
*endif
*endif
*enddo
neorder(i1)=mine
*enddo
!**************************************************************
max_tem=1500 !按照前面假設(shè)，焊料的初始溫度為1500℃
dt1=1e-3 !用于建立初始條件的一個(gè)很小的時(shí)間段
dt=5 !焊接一個(gè)單元所需的時(shí)間
t=0 !起始時(shí)間
esel,all
eplot
/auto,1
/replot
*do,i,1,nse
ekill,neorder(i)
esel,s,live
eplot
*enddo
allsel,all
outres,all,all
ic,all,temp,20
kbc,1
timint,0,struct
timint,1,therm
timint,0,mag
tintp,0.005,,,1,0.5,0.2
!
nsub1=2
nsub2=40
!*************************************************
*do,i,1,nse
ealive,neorder(i)
esel,s,live
eplot
esel,all
!******下面的求解用于建立溫度的初始條件******
t=t+dt1
time,t
nsubst,1
*do,j,1,4
d,nelem(neorder(i),j),temp,max_tem
*enddo
solve
!****下面的求解用于保證初始的升溫速度為零****
t=t+dt1
time,t
solve
!*********下面的步驟用于求解溫度分布**********
*do,j,1,4
ddele,nelem(neorder(i),j),temp
*enddo
t=t+dt-2*dt1
time,t
nsubst,nsub1
solve
*enddo
t=t+50000 !*********下面的步驟用于冷卻過(guò)程求解*****
time,t
nsubst,nsub2
solve
save
finish
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!后處理過(guò)程!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/post1
!**************下面的一系列命令用于生成應(yīng)力的動(dòng)畫文件*******
/seg,dele
/cont,1,15,0,1200e6/16,1200e6
/dscale,1,1.0
avprin,0,0
avres,1
/seg,multi,stress1,0.1
esel,all
*do,i,1,nse
esel,u,elem,,neorder(i)
*enddo
*do,i,1,nse
esel,a,elem,,neorder(i)
set,(i-1)*3+1,1
plnsol,s,eqv
*do,j,1,nsub1
set,(i-1)*3+3,j
plnsol,s,eqv
*enddo
*enddo
*do,i,1,nsub2
set,(nse-1)*3+4,i
plnsol,s,eqv
*enddo
/seg,off,stress1,0.1
/anfile,save,stress1,avi
!**********下面的一系列命令用于生成溫度的動(dòng)畫文件************
/seg,dele
/cont,1,15,0,1500/16,1500
/dscale,1,1.0
avprin,0,0
avres,1
/seg,multi,temp1,0.1
esel,all
*do,i,1,nse
esel,u,elem,,neorder(i)
*enddo
*do,i,1,nse
esel,a,elem,,neorder(i)
set,(i-1)*3+1,1
plnsol,temp
*do,j,1,nsub1
set,(i-1)*3+3,j
plnsol,temp
*enddo
*enddo
*do,i,1,nsub2
set,(nse-1)*3+4,i
plnsol,temp
*enddo
/seg,off,temp1,0.1
/anfile,save,temp1,avi
finish