希望對初學者能有幫助，耦合問題確實比較麻煩，特別是前期的收斂，以及效果的調試，耗時長，參數(shù)不易控制。

;流體與動態(tài)計算實例分析---大壩
new
conf dyn fluid;設置動態(tài)與流體算法
set dyn off fluid off;關閉動態(tài)與流體算法
; generate foundation and embankment grids and attach interfaces
;生成基礎和堤壩網(wǎng)格并粘貼接觸面
gen zone bri p0 0,0,0 p1 40,0,0 p2 0,10,0 p3 0,0,10 size 20 5 5;基礎
gen zone bri p0 22,0,10 p1 40,0,10 p2 22,10,10 p3 22,0,20 size 9,5,5;堤壩
;在z=10,x=15~22,y=0~10上生成接觸面1
interface 1 face range x 15.0 22.0 y 0.0 10.0 z 9.9 10.1
;在x=22,z=10~21,y=0~10上生成接觸面2
interface 2 face range x 21.9 22.1 y 0.0 10.0 z 10.0 21.0
;設置最大的邊界長度為1.0
interface 1 maxedge 1.0
interface 2 maxedge 1.0
; generate block wall 生成擋水墻
gen zone bri p0 15,0.5,11 p1 21,0.5,11 p2 15,9.5,11 p3 15,0.5,20.9 siz 3 5 5
; name groups and move block on to soil
;命名群組并移動擋水墻到土壤上
group block range x=16,22 y=0,10 z=10,20
group 'soil embankment' range x=22,40 y=0,10 z=10,20
group 'dense soil foundation' range x=0,40 y=0,10 z=0,10
;擋墻沿x方向增加一個單位
ini x add 1.0 range group block
;擋墻沿z方向增加一個單位
ini z add -1.0 range group block
; assign models to groups
;給群組設定計算模型
model mohr range group block not;除擋墻外的群組為摩爾庫侖模型
model elas range group block;擋墻為彈性
; assign mechanical properties設置力學參數(shù)
prop shear=1e8 bulk=2e8 cohes=1e10 range group 'soil embankment'
prop shear=5e8 bulk=1e9 cohes=1e10 range group 'dense soil foundation'
prop shear=9.15e9 bulk=10e9 range group block
ini dens=2100 range group block;初始化質量密度
ini dens=1800 range group block not
interface 1 prop coh=0 fric 60. dil 0. kn=1e8 ks=1e8 ten 0.;接觸面參數(shù)
interface 2 prop coh=0 fric 60. dil 0. kn=1e8 ks=1e8 ten 0.
model fl_iso;各項同性流體模型,計算流體必須的.
; mechanical boundary and initial conditions物理邊界和初始條件
fix z range z=-.1 .1;固定z=0的面
fix x range x=-.1 .1
fix x range x=39.9 40.1;固定x=40的面
fix y range y=-.1 .1
fix y range y=9.9 10.1
;初始應力,垂直應力為水平的2倍,在z方向有梯度變化
ini szz -3.6e5 grad 0 0 1.8e4
ini sxx -1.8e5 grad 0 0 0.9e4
ini syy -1.8e5 grad 0 0 0.9e4
set grav 0 0 -10;設置重力加速度
;記錄監(jiān)測數(shù)據(jù)
hist unbal;不平衡力
hist gp zdisp 16,5,20;點(16,5,20)的z方向位移
hist gp zdisp 30,5,20
;求解
solve
save block1.sav;保存
; assign realistic strength properties設置現(xiàn)實的強度參數(shù)
prop cohes=0 tens 0 fric 35 range group 'soil embankment'
prop cohes=0 tens 0 fric 40 range group 'dense soil foundation'
solve
save block1.sav

;流體分析
rest block1.sav;調用保存的文件
; specify fluid properties設定流體參數(shù)
prop perm=1e-8 poros=0.3
ini fdens=1000;初始化流體密度
ini fmod=2e3;流體的體積模量
set fluid pcut on;設置流體進程,但pcut是??
; assign water table設置水位
water density 1000.;水的密度
water table face 0 0 20 0 10 20 40 10 20 40 0 20 ;水平面由四個節(jié)點創(chuàng)建
; block wall is impermeable擋墻不透水
fix pp 0 range group block;擋墻區(qū)域內(nèi)孔隙水壓力為0
;施加水壓力
apply nstress -1e5 range x=0,16 y=0,10 z=9.9,10.1;加在土壩上的
apply nstress -2e5 grad 0,0,1e4 range x=15.9,16.1 y=0,10 z=10,20;擋墻上的z向梯度變化
;啟動流體算法
set fluid on
solve
save block2.sav

;動態(tài)分析
rest block2.sav
set dyn on;啟動動態(tài)算法
set large;大變形
set dyn multi on;設置動態(tài)多步計算,有什么區(qū)別呢

;turns multi-stepping on or off. Multi-stepping speeds up calculations in dynamic models which have a large
;zone size or modulus contrast. Sub-stepping only works when dynamic mode is in operation (SET dyn on),
;and is effective only when the grid is nonuniform or there is a contrast in material properties.
;初始化速度,位移和狀態(tài)
ini xvel 0 yvel 0 zvel 0
ini xdisp 0 ydisp 0 zdisp 0
ini state 0
;設置土中水的模量
; set fluid modulus for water in soils
ini fmod 250e6 range group block not
;施加動態(tài)邊界條件
; apply dynamic boundary conditions
def wave
wave = ampl * sin (2.0*pi*freq*dytime)
end
;釋放邊界z=0
free x y range z -.1 .1
;施加動態(tài)條件?
apply xvel 1.0 hist wave ran z -.1 .1
apply yvel 1.0 hist wave ran z -.1 .1
apply ff
set freq 10.0 ampl 0.5 ;設置頻率和放大系數(shù)
;
; dynamic histories 動態(tài)歷史記錄
set dyn time 0
hist reset
hist dytime
hist gp xvel 20,10,0
hist zone pp 19,5,5 ;記錄點孔隙壓力
hist zone pp 30,5,5
hist zone pp 30,5,15
hist zone pp 19,5,9
hist gp xdis 16,5,20
;
set dyn damp local .125 ;設置動態(tài)本地衰減為.125
solve age 5.0 ;求解的動態(tài)計算時間
save block3.sav
ret



來自:科研中國