摘要：實際結構的共振現象中常常會出現拍現象，這讓很多工程師誤以為共振就會引起拍現象。本文從振動理論，結構仿真，信號實踐三個角度闡述這兩個現象是完全不一樣的，并且給出實際結構的共振現象中常常會出現拍現象的原因。

---

拍：兩個頻率相近的波疊加之后會形成忽大忽小的幅值。

共振：在共振頻率下，很小的激勵便可產生很大的振動。

---

1 振動理論

查閱相關理論，很容易發現，共振就是結構振幅很大，從來不會提及振幅忽大忽小的現象。所以在理論中，并沒有將共振現象和拍現象相提并論，相互混淆。即，理論上共振和拍是相區別的。

---

2 結構仿真

定義三自由振動系統，模態分析：

finish !初始化
/clear !清空所有數據
/filname,3dof! 定義文件名
/title, tansient car!定義文件標題
!
m1=5!質量1
m2=15!質量2
m3=20!質量3
k1=110000!剛度1
k23=50000!剛度2,3
c23=100!阻尼2,3
!
/prep7!進入前處理模塊
et,1,mass21,,,4!定義質量單元
et,2,combin14,,,2!定義彈簧單元
r,1,m1!質量實常數 1
r,2,m2!質量實常數2
r,3,m3!質量實常數3
r,4,k1!剛度實常數4
r,5,k23,c23!剛度，阻尼實常數5
!
n,1,0,0!節點1
n,2,0,1!節點2
n,3,0,2!節點3
n,4,0,3!節點4
type,1!選擇質量單元
real,1!實常數1
e,2!質量單元
real,2!實常數2
e,3!質量單元
real,3!實常數3
e,4!質量單元
type,2!選擇彈簧單元
real,4!實常數4
e,1,2!彈簧單元
real,5!實常數5
e,2,3!彈簧單元
e,3,4!彈簧單元
!
d,all,ux! 約束X方向自由度，只留下Y自由度
d,1,all!約束輪胎位置
!
finish !初始化
/solu !進入求解模塊
antype,2!模態分析
modopt,qrdamp,6  !QRDAMP法
!modopt,lanb,6 !LANB法
mxpand,6,,,yes! 提取結果
allsel!全選
solve! 求解
!
finish !初始化
/post1!進入后處理模塊
set,list!提取模態頻率

求解結果如下：

構建包含3個共振頻率的激勵信號，對該振動系統進行時程分析：

構建信號：

信號頻域：

時程分析：

finish !初始化
/clear !清空所有數據
/filname,3dof! 定義文件名
/title, tansient car!定義文件標題
!
m1=5!質量1
m2=15!質量2
m3=20!質量3
k1=110000!剛度1
k23=50000!剛度2,3
c23=100!阻尼2,3
!
/prep7!進入前處理模塊
et,1,mass21,,,4!定義質量單元
et,2,combin14,,,2!定義彈簧單元
r,1,m1!質量實常數 1
r,2,m2!質量實常數2
r,3,m3!質量實常數3
r,4,k1!剛度實常數4
r,5,k23,c23!剛度，阻尼實常數5
!
n,1,0,0!節點1
n,2,0,1!節點2
n,3,0,2!節點3
n,4,0,3!節點4
type,1!選擇質量單元
real,1!實常數1
e,2!質量單元
real,2!實常數2
e,3!質量單元
real,3!實常數3
e,4!質量單元
type,2!選擇彈簧單元
real,4!實常數4
e,1,2!彈簧單元
real,5!實常數5
e,2,3!彈簧單元
e,3,4!彈簧單元
!
d,all,ux! 約束X方向自由度，只留下Y自由度
!
finish! 初始化
ni=2560!掃頻數據點個數
dt=1/256!掃頻點時間間隔
*dim,impact,array,ni !定義參數
*vread,impact(1),gzh,txt !讀取連續沖擊時域數據
(f9.6) !定義格式
allsel!全選
/solu!進入求解模塊
antype,4 !瞬態分析
trnopt,full,,,,,hht !完全法
timint,on !時間積分打開
nlgeom,off!忽略幾何非線性
*do,i,1,ni !循環加載
time,i*dt! 時間點
d,1,uy,0.005*impact(i) !位移激勵
kbc,0!斜坡荷載
nsubst,1,10,1!定義子步
allsel!全選
outres,all,last!輸出每個荷載步的計算結果
solve!求解
save!保存
*enddo  !循環結束

提取響應加速度：

/POST26  !進入后處理模塊

NSOL,2,4,ACC,Y !提取變量
*DIM,ACCY4,ARRAY,NI!定義參數
VGET,ACCY4(1),2 !將變量寫入參數
*CFOPEN,ACCY4,txt
*VWRITE,ACCY4(1)!將參數寫入文件
(F16.9)
*CFCLOS

NSOL,3,4,VEL,Y !提取變量
*DIM,VELY4,ARRAY,NI!定義參數
VGET,VELY4(1),3 !將變量寫入參數
*CFOPEN,VELY4,txt
*VWRITE,VELY4(1)!將參數寫入文件
(F16.9)
*CFCLOS

NSOL,4,4,U,Y !提取變量
*DIM,UY4,ARRAY,NI!定義參數
VGET,UY4(1),4 !將變量寫入參數
*CFOPEN,UY4,txt
*VWRITE,UY4(1)!將參數寫入文件
(F16.9)
*CFCLOS

NSOL,5,1,U,Y !提取變量
*DIM,UY1,ARRAY,NI!定義參數
VGET,UY1(1),5 !將變量寫入參數
*CFOPEN,UY1,txt
*VWRITE,UY1(1)!將參數寫入文件
(F16.9)
*CFCLOS

顯示加速度響應的時域和頻域：

從以上兩個圖可得：

1 當激勵中包含結構共振頻率時，結構會產生共振現象；

2 結構仿真中，共振時的時域響應不一定有拍現象；

---

3 信號實踐

不難發現，只要信號頻譜中存在相近的頻率，就會從產生拍現象：

---

4 實際結構

本文的最后回到最初的問題：為什么實際結構的共振現象中常常會出現拍現象？

經過以上三個基本角度的分析，以及振動測試實踐。可能存在兩個原因，導致共振現象中出現拍現象：

第一：調制。如果在共振頻率附近發生了調制，就會在共振頻率附近出現多個相近頻率，這樣就滿足了存在相近頻率條件，所以產生拍現象。

第二：非線性。當結構發生共振現象時，測試得到的頻譜在共振頻率處最大，但在共振頻率周邊幅值也可能不小。這樣就滿足了存在相近頻率條件，所以產生拍現象。即便周邊的頻率幅值為共振幅值的1/3，從時域上也可能觀察到明顯的拍現象。

---

5 總結

1 拍現象的根本原因是頻譜存在相鄰頻率（幅值都較大）；

2 共振一般都會在頻譜上產生相鄰頻率幅值都較大（調制和非線性），所以實際結構的共振現象中常常會出現拍現象；

3 時域上出現拍現象，不表示結構發生了共振。也有可能剛好存在頻譜相近的兩個激勵。

4 在實際工作中，看到拍現象時，可以猜測發生了結構共振，但不足以下定論。