!參照《ANSYS結構動力分析與應用》王新敏編著中瞬態分析
!梁上移動質量的瞬態分析（移動荷載+位移耦合法）
FINISH$/CLEAR$/CONFIG,NRES,2000
/PREP7
LB=20$NE=400$NN=NE+1$NN1=NN+1$NE1=NE+1        !梁長，梁單元數，節點數，移動質量節點，總單元數
M1=1000$M2=3000$V=72/3.6                                            !質量作用梁的力，運行速度
DELTL=LB/NE                                     !梁劃分單元的長度，在一個梁單元上運行時間
DELTT=DELTL/V                                 !在一個梁單元上運行時間
B=0.3$H=0.6                                      !梁寬，梁高
EM=2.1E11$AREA=B*H$IM=1/12*B*H*H*H            !彈性模量，面積，慣性矩
DENG=7800$GRA=9.81                                             !密度，加速度
K1=3E6$C1=1E4
F1=ACOS(-1)/2/LB/LB*SQRT(EM*IM/(AREA*DENG))   !自振頻率（Hz）
ET,1,BEAM3
MP,EX,1,EM$MP,NUXY,1,0.3$MP,DENS,1,DENG
R,1,AREA,IM,H  
*DO,I,1,NN$N,I,(I-1)*DELTL$*ENDDO
*DO,I,1,NE$E,I,I+1$*ENDDO 

ET,2,MASS21,,,4$R,2,M1$R,3,M2                  !定義質量2D無轉動
ET,3,14,,2$R,4,K1,C1                                      !定義剛度，彈簧
N,NN1,0,0$N,NN1+1,0,0
TYPE,2$REAL,2
E,NN1
TYPE,2$REAL,3
E,NN1+1
TYPE,3$REAL,4$E,NN1,NN1+1
D,1,UX,,,,,UY$D,NN,UY                          !施加梁約束和質量單元約束
D,NN1,UX,,,,,UY
F,NN1,FY,-M1*GRA                               !施加慣性力自重
F,NN1+1,FY,-M2*GRA
FINISH
!----------------------------------------------------------------------------------------------------------------
/SOLU
ANTYPE,4
OUTRES,ALL,ALL
AUTOTS,ON
!靜力分析
TIMINT,OFF                           !關閉瞬態效應
TIME,0.005                            !定義時間（小時間間隔）
DELTIM,DELTT/10$KBC,0$SOLVE          !求解
TIME,0.1$SOLVE
!----------------------------------------------------------------------------------------------------------------
!質量在梁跨內的瞬態分析
TIMINT,ON                            !打開瞬態效應，設置輸出控制
ALPHAD=0                            !瑞利阻尼
BETAD=0
NSUBST,1                                !1個載荷子步
DDELE,NN1,UY                        !刪除質量單元的uy約束
DDELE,NN1+1,UY
*DO,I,2,NN
FDELE,I-1,ALL
TIME,(I-1)*DELTT+0.1                   !定義荷載步結束時間
D,NN1,UX,(I-1)*DELTL                   !對質量節點時間位移（根據速度施加）
D,NN1+1,UX,(I-1)*DELTL
CPDELE,ALL,ALL                        !刪除所有既有耦合方程
CP,NEXT,UY,I,NN1                     !將質量節點與梁節點耦合uy自由度
SOLVE
SAVE
*ENDDO
!----------------------------------------------------------------------------------------------------------------
!質量移出梁跨的瞬態分析（自由振動）
CPDELE,ALL
FDELE,NN,ALL
D,NN1,UX,LB+1                         !將質量塊移出梁跨并施加uy約束
D,NN1+1,UX,LB+1
D,NN1,UY
TIME,LB/V+5/F1                       !荷載結束時間增加5個周期（考慮自由振動）
SOLVE
SAVE
FINISH   
!----------------------------------------------------------------------------------------------------------------
/POST26
NC=NODE(LB/2,0,0)
NSOL,2,NC,U,Y
PLVAR,2
ANSYS采用位移建立車橋耦合模型，進行瞬態分析，車在橋跨內的響應沒有問題，但是當車離開橋后的自由振動的響應為一條斜直線，怎么調都不對，請朋友們幫幫忙，看看自由振動的命令流哪里不對，或者說下自由振動的分析步驟也行，在下感激不盡！